[오토핫키] 캡챠 구현

; Captcha example by Titan

 

Gui, + ToolWindow

Gui, Add, Text, x10 y10 w75, Enter the code:

Pass := Captcha(90, 10)

Gui, Add, Edit, vInput x90 y50 w50

Gui, Add, Button, gGo default x145 y50 h20, Enter

Gui, Show, , Captcha

Return

 

Go:

Gui, Submit, NoHide

If Input != % Pass

  MsgBox, 16, Error, You didnt enter the code correctly!`n`nThe code was: %Pass%

else

  MsgBox, 64, Cool, done!`n`nThe code was: %Pass%

Return

 

~* Esc::

GuiClose:

ExitApp

 

Captcha(x, y, len=6, lvl=0, gui=1)

{

  ; Captcha by Titan

  w := len * 15 + 10

  h := 35

  Gui, %gui%: Add, Text, Border Section x%x% y%y% w%w% h%h%

  xw := x + 10

  Loop, % len

  {

    Gui, Font, % Random("Styles") "w" Random("Number", 1, 1000) "s" Random("Number", 8, 12) "c" Random("Colour"), Random("Font")

    key := Pass(1)

    keys = %keys%%key%

    yw := "ys+" Random("Number", 3, 10)

    Gui, %gui%: Add, Text, BackgroundTrans x%xw% %yw%, % key

    xw += % Random("Number", 10, 15)

  }

  Gui, Font

  if (lvl = 1)

  {

    yw = 5

    Loop, % ( Floor(w/3))

      dots = %dots%.

    Loop, 5

    {

      Gui, Font, % "w1" "c" Random("Colour")

      Gui, %gui%: Add, Text, BackgroundTrans + Wrap x%x% y%yw% w3, % dots

      yw += 5

    }

    Gui, Font

  }

  Return, % keys

}

 

Pass(len=5, chars=0)

{

  ; Captcha module by Titan

  chAlpha = abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ

  chNum = 1234567890

  chAlphaNum = %chAlpha%%chNum%

  If chars in 0,alphanum

    StringSplit, list, chAlphaNum

  else If chars in 1, alpha

    StringSplit, list, chAlpha

  else If chars in 2,num

    StringSplit, list, chNum

  Loop, % len

  {

    Random, rnd, 1, % list0

    i := list%rnd%

    pass = %pass%%i%

  }

  Return, pass

}

 

Random( type, p1=0, p2=0)

{

  ; Captcha module by Titan

  If type in Number

    Random, r, % p1, % p2

  else If type in Font

  {

    Fonts = Arial,Courier,Courier New,Lucida Console,MS Sans Serif,MS Serif,Tahoma,Times New Roman

    StringSplit, Fonts, Fonts, `,

    Random, r, 1, %Fonts0%

    r := Fonts%r%

  }

  else If type in Colour

  {

    Colours = Black,Green,Silver,Lime,Gray,Olive,White,Yellow,Maroon,Navy,Red,Blue,Purple,Teal,Fuchsia,Aqua

    StringSplit, Colours, Colours, `,

    Random, r, 1, %Colours0%

    r := Colours%r%

  }

  else If type in Styles

  {

    Styles = bold, underline, norm,0x7,0x4,0x1,0x10,0x11,0x8,0x5,0xC,0x80,0x100,0x2,0x1000,0x9,0x6

    StringSplit, Styles, Styles, `,

    Random, r, 1, %Styles0%

    r := Styles%r%

  }

  Return, % r

}

출처: http://nimto.tistory.com/691 [ㄴrㅎnㅂrㄹrㄱi]